home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Atari Mega Archive 2
/
Atari Mega Archive CD - Volume 2.iso
/
8bit
/
cislib_a
/
gr0dmp.lst
< prev
next >
Wrap
File List
|
1995-04-22
|
1KB
|
19 lines
32200 REM " SCRNPRTT.SUB Ver 1.0
32210 REM " 02/26/85 - Bob Geayer
32220 REM " CIS ppn: 71425,463
32230 REM " User Group: JACS (NJ)
32240 REM VARIABLES: A, E, HOME, INVERSE, L, P
32245 REM " Dumps Graphics 0 screen to printer (or other device)
32250 TRAP 32340:CLOSE #5:OPEN #5,8,0,"D2:TST":? #5:SOUND 0,0,0,0
32260 HOME=PEEK(88)+256*PEEK(89)
32270 FOR L=0 TO 23: FOR P=0 TO 39:A=PEEK(L*40+P+HOME)
32280 INVERSE=0:IF A>127 THEN INVERSE=1:A=A-128
32290 IF A<64 THEN A=A+32:GOTO 32310
32300 IF A>63 AND A<96 THEN A=A-64
32310 IF INVERSE THEN A=A+128:REM ********* Delete this line if your printer
32320 REM or interface can't handle inverse.
32330 ? #5;CHR$(A);:NEXT P:? #5:NEXT L:TRAP 40000:CLOSE #5:RETURN
32340 E=PEEK(195):L=PEEK(186)+256*PEEK(187):IF E<>138 THEN ? :? "ERROR ";E:LIST L:CLOSE #5:STOP
32350 ? "IS PRINTER ONLINE?": FOR A=15 TO 0 STEP -0.1:SOUND 0,120,10,A:NEXT A
32360 ? "IS INTERFACE ONLINE?": FOR A=15 TO 0 STEP -0.4:SOUND 0,120,10,A:NEXT A:GOTO L